한국어
Qt
 

QML and Qt Quick QML에서 D-Bus 통신

makersweb 2023.03.15 17:47 조회 수 : 547

Nemo Mobile D-Bus QML 플러그인을 사용하면 시스템 및 세션 버스의 서비스에 액세스하고 자체 서비스를 제공할 수 있다. D-Bus는 프로세스 간 통신에 사용된다.

 

저장소: https://github.com/sailfishos/nemo-qml-plugin-dbus

 

QML Types

이 모듈에는 다음 QML 유형이 제공된다.

  • DBusAdaptor : DBusAdaptor 개체는 시스템 또는 세션 버스에서 D-Bus 서비스를 제공하는 데 사용할 수 있다. 서비스가 활성화되어 있는 한 시스템의 다른 응용 프로그램에서 이 서비스를 호출할 수 있다. QML의 DBusAdaptor는 D-Bus를 통해 간단한 객체를 노출하는 수단을 제공하기 위한 것이다. 보다 복잡한 사용 사례의 경우 C++ 및 Qt DBus 모듈을 사용하는 것이 좋다.
  • DBusInterface : DBusInterface 개체는 시스템 및 세션 버스에 있는 개체의 메서드를 호출하고 신호(signalsEnabled 참조)를 수신하고 해당 개체의 속성을 읽는 데 사용할 수 있다.

Examples

세션 버스 개체에서 함수 호출

import QtQuick 2.0
import Nemo.DBus 2.0

Item {
    DBusInterface {
        id: profiled

        service: 'com.nokia.profiled'
        iface: 'com.nokia.profiled'
        path: '/com/nokia/profiled'
    }

    Component.onCompleted: {
        // Call the "set_profile" method here
        profiled.call('set_profile', ['silent']);
    }
}

 

함수 호출 및 반환 값 얻기

import QtQuick 2.0
import Nemo.DBus 2.0

Item {
    DBusInterface {
        id: profiled

        service: 'com.nokia.profiled'
        iface: 'com.nokia.profiled'
        path: '/com/nokia/profiled'
    }

    Component.onCompleted: {
        // Call the "get_profile" method without arguments, and
        // when it returns, call the passed-in callback method
        profiled.typedCall('get_profile', [], function (result) {
            // This will be called when the result is available
            console.log('Got profile: ' + result);
        });
    }
}

 

D-Bus 객체의 시그널 수신

import QtQuick 2.0
import Nemo.DBus 2.0

Item {
    DBusInterface {
        id: profiled

        service: 'com.nokia.profiled'
        iface: 'com.nokia.profiled'
        path: '/com/nokia/profiled'

        signalsEnabled: true

        function profile_changed(changed, active, profile, values) {
            if (changed && active)
                console.log("Profile changed to:", profile)
        }
    }
}

 

 

ConnMan 의 D-Bus 제어 인터페이스를 통해 네트워크 연결 상태 감지

 

ConnMan은 Linux 를 실행하는 임베디드 장치에 중점을 둔 인터넷 연결 관리자다. 인터넷 연결을 관리하기 위한 연결 관리 데몬(connmand)이 있고 이 데몬은 D-Bus 제어 인터페이스를 제공한다. 따라서 응용프로그램은 D-Bus를 사용하여 ConnMan 서비스를 이용할 수 있다.

 

다음은 DBusInterface 개체를 통해 QML에서 간단하게 connmand 과 연결하고 인터넷 연결 상태가 바뀔 때마다 UI에 표시하는 방법을 보여준다.

import QtQuick 2.15
import QtQuick.Window 2.15
import Nemo.DBus 2.0

Window {
    width: 640
    height: 480
    visible: true
    title: qsTr("Network State")

    DBusInterface {
        id: connmanManager

        // Connman on the D-Bus system bus
        bus: DBus.SystemBus

        service: 'net.connman'
        iface: 'net.connman.Manager'
        path: '/'

        signalsEnabled: true

        // Will be called when the "PropertyChanged" signal is received.
        function propertyChanged(p, v) {
            console.log("Property Changed:", p, v)
            if ( p === 'State' ) {
                state.text = v
            }
        }
    }

    Column {
        anchors.centerIn: parent
        Text {
            id: stateLabel
            text: "네트워크 상태"
            font.pixelSize: 28
            horizontalAlignment: Text.AlignHCenter
        }
        Text {
            id: state
            width: parent.width

            font.pixelSize: 22
            horizontalAlignment: Text.AlignHCenter
        }
    }
}

 

ConnMan_State.png

번호 제목 글쓴이 날짜 조회 수
공지 Qt프로그래밍(QtQuick) Beginner를 위한 글 읽는 순서 운영자 2019.01.05 85364
176 가상키보드(Qt Virtual Keyboard)를 사용하는 방법 [32] file makersweb 2019.05.03 219982
175 콘솔에서 사용자 입력받기 file makersweb 2020.03.22 51791
174 QString 문자열 다루기 예제 운영자 2019.01.26 39611
173 Windows에서 Qt 설치 따라하기 file makersweb 2019.10.14 30791
172 Qt의 시그널 슬롯 시스템 file makersweb 2015.10.20 23435
171 QThread 소개 및 예제 makersweb 2019.12.25 19232
170 QtCreator Design으로 GUI만들기 (QML로 만드는 Hello World -2) [1] file makersweb 2019.05.26 14772
169 초보자를 위한 첫번째 프로젝트 - QML로 만드는 Hello World file makersweb 2018.03.16 14360
168 Qt 프로그래밍의 시작 makersweb 2015.10.25 14326
167 Qml과 C++로 구현하는 GUI어플리케이션 file makersweb 2018.12.25 13832
166 QML과 QtQuick 모듈 개념과 기본 타입들 makersweb 2019.04.26 13325
165 Windows에서 라즈베리파이3용 Qt5.10.0 크로스컴파일 [20] file makersweb 2018.02.23 12719
164 Qt의 오픈소스 라이센스 소개 file makersweb 2019.12.15 12384
163 Qml 기본 컴포넌트 강좌 (1) file makersweb 2019.01.03 11978
162 QtSerialPort를 사용한 시리얼(Serial)통신 [3] makersweb 2019.05.21 11761
161 Qt Installer Framework - 패키징, 설치프로그램 제작 file makersweb 2018.10.14 11601
160 Qt 응용프로그램 배포(windows) file makersweb 2018.10.10 11173
159 Ubuntu Linux에서 Qt Creator 설치 file makersweb 2016.03.06 10647
158 Qt의 스레드간 시그널 슬롯의 커넥션타입 [1] makersweb 2015.10.24 10106
157 QML 강좌 - 동적 Listing (ListView) file makersweb 2019.06.01 10030